Ich schaffe es einfach nicht, dass ein Beet automatisch mit dem Eimer gegossen wird. Die Eingabe "giess" sollte eigentlich dazu führen. Es wird aber nur versucht den Eimer mit sich slebst zu gießen.

Include German Mistype by Team GerX.

The lab is a room. "Hier gibt es ein Beet und einen Brunnen.".

Sparkling it with is an action applying to two things requiring light.

Understand "giess [something] mit [dativ] [something]" as sparkling it with.

Understand "giess [something] auf [something]" as sparkling it with (with nouns reversed).

Understand "giess [something] aus auf [something]" as sparkling it with (with nouns reversed).

Understand "kipp [something] auf [something]" as sparkling it with (with nouns reversed).

Understand "leer [something] auf [something]" as sparkling it with (with nouns reversed).

Understand "leer [something] aus auf [something]" as sparkling it with (with nouns reversed).

Understand "giess mit [something] [something]" as sparkling it with (with nouns reversed).

Table of infinitives (continued)

Verb   Infinitive

"leer"   "leeren"

[die erste understand-regel soll oberste priorität haben beim Nachfragen]

The sparkling it with action translates into I6 as "SparkleWith".

Include (-

Extend 'giess' first

* noun 'mit' DATIVE_TOKEN held -> SparkleWith

;

-) before "Flex.i6t".

Check sparkling it with:

   if second noun is not a carried thing:

      if the second noun is a worn thing:

         say "Mit [dem second Noun] kann man nicht gießen." instead;

      otherwise:

         say "Du kannst nur mit Sachen gießen, die Du bei Dir trägst." instead;

   otherwise if second noun is not a bucket:

      say "Mit [dem second Noun] kann man nicht gießen." instead.

   

Carry out sparkling it with:

   say "[Der Noun] [if the noun is plural-named]müssen[otherwise]muss[end if] nicht gegossen werden.".

      

The well is a male scenery container in the lab. The printed name of the well is "Brunnen". Understand "Brunnen" and "loch [n]" as well. The description of the well is "Ein Ring aus Feldsteinen, welcher ein Loch im Boden umschließt, in dem lustig Wasser hin und her schwappt.".

The well water is a neuter scenery in the well. The printed name of the well water is "Brunnenwasser". Understand "wasser" and "brunnenwasser" as water. The special indefinite article of the well water is NO ARTICLE. The description of the well water is "Frisches, klares Brunnenwasser.".

The vegetable patch is a neuter scenery in the lab. The printed name of the vegetable patch is "Gemüsebeet". Understand "beet" and "gemuesebeet" and "erde [f]" as vegetable patch.

A bucket is a kind of thing.

The old bucket is a male bucket in the lab. The printed name of the old bucket is "alt[^] Eimer". Understand "eimer" and "wasser" as old bucket. The description of it is "Ein alter verbeulter Eimer voller Wasser.".

Does the player mean sparkling something with the old bucket:

   it is likely.

Does the player mean sparkling the vegetable patch with the old bucket:

   it is very likely.

   

Does the player mean sparkling the noun with the noun:

   it is very unlikely.

   

Does the player mean sparkling the old bucket with something:

   it is very unlikely.```

Das Füllen des Eimers mit Wasser und die Folgen des Gießens habe ich bewußt aus dem Bespiel entfernt um es nicht zu überfrachten.

Die letzte Anweisung sollte eigentlich unnötig sein, aber auch sie verhindert nicht, dass primär der Eimer gegossen wird.

```>giess

(den alten Eimer mit dem alten Eimer)```

Hallo,

ein Vorschlag:

"Testguss" by Mikawa.

Include German by Team GerX.

The lab is a room. "Hier gibt es ein Beet und einen Brunnen.".

Sparkling it with is an action applying to two things requiring light.

Understand "giess [something] mit [dativ] [something preferably held]" as sparkling it with.

Table of infinitives (continued)

Verb   Infinitive

"leer"   "leeren"

Check sparkling it with:

   if second noun is not a carried thing:

      if the second noun is a worn thing:

         say "Mit [dem second Noun] kann man nicht gießen." instead;

      otherwise:

         say "Du kannst nur mit Sachen gießen, die Du bei Dir trägst." instead;

   otherwise if second noun is not a bucket:

      say "Mit [dem second Noun] kann man nicht gießen." instead.

 

Carry out sparkling it with:

   say "[Der Noun] [if the noun is plural-named]müssen[otherwise]muss[end if] nicht gegossen werden.".

The well is a male scenery container in the lab. The printed name of the well is "Brunnen". Understand "Brunnen" and "loch [n]" as well. The description of the well is "Ein Ring aus Feldsteinen, welcher ein Loch im Boden umschließt, in dem lustig Wasser hin und her schwappt.".

The well water is a neuter scenery in the well. The printed name of the well water is "Brunnenwasser". Understand "wasser" and "brunnenwasser" as water. The special indefinite article of the well water is NO ARTICLE. The description of the well water is "Frisches, klares Brunnenwasser.".

The vegetable patch is a neuter fixed in place in the lab. The printed name of the vegetable patch is "Gemüsebeet". Understand "beet" and "gemuesebeet" and "erde [f]" as vegetable patch.

A bucket is a kind of thing.

The old bucket is a male bucket in the lab. The printed name of the old bucket is "alt[^] Eimer". Understand "eimer" and "wasser" as old bucket. The description of it is "Ein alter verbeulter Eimer voller Wasser.".

Does the player mean sparkling the bucket with: it is very unlikely.

Test me with "nimm eimer / giess / lege eimer ab / giess"

Die Disambiguisierung verhindert, wenn möglich das Gießen des Eimers selbst und nimmt stattdessen ein Objekt, welches NICHT scenery ist. (Falls nur scenery Objects außer dem Eimer da sind, wird nachgefragt)

Eine andere Methode wäre, ein neues Attribut zu vergeben, also das Beet "sparkle-able" zu machen und die Aktion nur für sparkle-able things zuzulassen -- das wäre aber umständlich und würde bei nicht-sparkle-able things zu einer komischen Fehlermeldung führen ...

Grüße

-- MI

Oder Du bohrst Dein per I6-Inklusion priorisiertes Satzmuster noch weiter auf (und setzt ein Attribut "sparkable", so wie von Michael vorgeschlagen, ein):

Attribute sparkable;

-) after "Definitions.i6t".

A thing can be sparkable. The sparkable property translates into I6 as "sparkable".

The vegetable patch is sparkable.

[die erste understand-regel soll oberste priorität haben beim Nachfragen]

The sparkling it with action translates into I6 as "SparkleWith".

Include (-

[ is_sparkable; if (noun has sparkable) rtrue; rfalse; ];

Extend 'giess' first

* noun=is_sparkable 'mit' DATIVE_TOKEN held -> SparkleWith

* noun 'mit' DATIVE_TOKEN held -> SparkleWith

;

-) before "Flex.i6t".```

Dann klappt's:

**Zitat:**
> >giess

(das Gemüsebeet mit dem alten Eimer)

Du kannst nur mit Sachen gießen, die Du bei Dir trägst.

Grüße,

Christian