# Nils' Bohrmaschine — 1 of 1

## Olaf Nowacki

Release 2

- Home page
- Complete text

"Nils' Bohrmaschine" by Olaf Nowacki (in German)

Include German by Team GerX.

Use skip libcheck.

[Use scoring.

The maximum score is 20.]

The story genre is "Comedy".

The story headline is "Eine interaktive [if loop is 0]Leihgabe[else]Zeitschleife[end if]".

The release number is 2.

The story description is "Wenn man vergisst, ausgeliehenes Werkzeug beizeiten zu retournieren, ist man dem Verleiher etwas schuldig.".

The story creation year is 2026.

Release along with a cover art ("Eine Selbstzahlerkasse in einem Supermarkt, auf der Bananen, ein Brötchen und eine Wasserflasche liegen."), an interpreter and the source text.

Volume 1 - Standards

Part 1 - player comments

After reading a command (this is the ignore beta-comments rule):

if the player's command matches the regular expression "^\W|\*|\+|\#":

say "(Notiert.)";

reject the player's command.

Part 2 - em-dash

To say -:

say "[unicode 8211]".

Part 3 - abouting

Abouting is an action out of world.

Report abouting:

say "'Was soll das alles hier?' fragst du so laut, dass es im ganzen Kassenbereich zu hören ist. [Der employee] nimmt Haltung an, räuspert sich und referiert dann mit monotoner Stimme:[paragraph break]'[bold type]Nils[apostrophe] Bohrmaschine[roman type] [-] hat überhaupt nichts mit Niels Bohr zu tun, und falls doch, dann nur ganz wenig. Ein riesengroßer Dank geht an Hannes Schüller, der mir mit Testen, Feedbacken und Lektorieren der unfertigen und fehlerhaften Vorversionen sehr geholfen hat! Das Spiel wurde im März 2026 von Olaf Nowacki für den IFGP 2026 geschrieben, das Cover wurde vom Autor selbst erstellt. Rückmeldungen und Transkripte sind sehr willkommen und möchten bitte an olaf.nowacki@gmail.com geschickt werden.'[paragraph break]Danach sackt [if nils is false]der Mann zurück in seine[else]die Frau zurück in ihre[end if] schlaffe Arbeitshaltung.".

Understand "about", "credits", "info", "ueber", "dank", "kolophon" as abouting.

Part 4 - helping

Helping is an action out of world.

Report helping:

say "Du rufst laut 'Hilfe!'[paragraph break][Der employee] schaut aus den Augenwinkeln zu dir rüber und findet offenbar, dass du keine Hilfe benötigst, denn [er] dreht sich einfach um und tut, als würde [er] dich nicht bemerken.".

Understand "hilf", "tipp", "hilf mir", "bitt hilf mir", "rat" as helping

Volume 2 - New Kinds & Globals

Part 1 - goods

A good is a kind of thing.

A good can be recorded. A good is usually not recorded.

A good has a real number called price.

Understand "ware/waren" as a good.

Part 2 - weight

Everything has a real number called weight.

A thing usually has weight 0.0001.

Part 3 - price

The shopping amount is a real number that varies.

To add (value - a real number):

increase shopping amount by value;

say "[line break]Auf dem Monitor der Kasse steht nun die neue: [italic type]Summe ¬ [shopping amount to 2 decimal places][roman type][paragraph break]".

Part 4 - Nils

Nils is a truth state that varies. Nils is false.

Volume 3 - Overwriting Standard Reactions

Part 1 - block drinking

The block drinking rule response (A) is "[Der noun] [ist] nicht zum Trinken geeignet.".

Part 2 - messing with fixed in place stuff

Instead of attacking, burning, cutting, opening, pulling, pushing, turning, switching off something fixed in place:

say "'[one of]Was wird das denn da[or]Würden sie das mal sein lassen[or]Soll ich den Wachdienst rufen[at random]?' [one of]ranzt[or]schnautzt[or]blafft[or]herrscht[or]fährt[or]pflaumt[or]giftet[at random] dich [the employee] an. Gute Frage.".

Part 3 - taking inventory

The supermarket print inventory rule is listed instead of the German print standard inventory rule in the carry out taking inventory rules.

Carry out taking inventory (this is the supermarket print inventory rule):

say "Du balancierst ";

list the contents of the player with accusative case, as a sentence, including contents, tersely, giving inventory information;

say " in deinen Händen.".

Part 4 - smelling

Instead of smelling, say "Es riecht nach einer Mischung aus Putzmitteln, künstlichem frisch-gebackene-Brötchen-Aroma und ausgelaufenen sauren Gurken.".

Part 5 - pushing (tippe auf)

Understand "tipp auf [dativ] [something]" as pushing.

Part 6 - waiting

Instead of waiting, say "Die Zeit scheint hier stillzustehen[first time]. Vielleicht bist du in einem schwarzen Loch?[paragraph break]Du schaust dich um und denkst, ja, das könnte tatsächlich sein[only].".

Part 7 - jumping

Instead of jumping, say "Du bist nicht in Sprungstimmung.[if the barrier is closed]. Außer... dein Blick schweift zum Ausgang[end if].".

Part 8 - inserting it into

Understand "fuehr [something] in [something] ein/--" as inserting it into.

Volume 4 - New Actions

Part 1 - scanning it with

A thing can be able to scan. A thing is usually not able to scan.

A thing can be scannable. A thing is usually not scannable.

Scanning it with is an action applying to two things.

Understand "scann [something] mit [dativ] [something] ein/--" as scanning it with.

Understand "zieh [something] an/vor/ueber [something] vorbei/--" as scanning it with.

Understand "halt [something] an/vor/ueber [something]" as scanning it with.

Understand "zeig [something] [dativ] [something]" as scanning it with.

Understand "zeig [dativ] [something able to scan] [something]" as scanning it with (with nouns reversed).

Understand the command "erfass", "buch", "verbuch", "scan" as "scann".

Understand "scann [something] ein/--" as scanning it with.

Rule for supplying a missing second noun while scanning:

if the noun is the receipt:

now the second noun is the camera;

else:

now the second noun is the scale.

Check scanning it with:

if the second noun is not able to scan, say "[The second noun] kann keine Barcodes einscannen." instead;

if the noun is not scannable, say "Du drehst [the noun] hin und her, findest aber keinen Barcode, den man einscannen könnte." instead.

Part 2 - drilling

Drilling is an action applying to two things.

Understand "bohr in/-- [something] mit [dativ] [something]" as drilling.

Understand "bohr mit [something] in [dativ] [something]" as drilling (with nouns reversed).

Understand "bohr in/-- [something]" as drilling.

Rule for supplying a missing second noun while drilling:

now the second noun is the drill.

Check drilling:

if the second noun is not the drill, say "[The second noun] kann es nicht ansatzweise mit der [drill] aufnehmen, wenn es ums Bohren geht." instead.

Carry out drilling:

say "Als du anfängst, mit der [second noun] kleine Löcher in [den noun] zu bohren, äugelt [the employee] stirnrunzelnd zu dir rüber, aber anscheinend kann [er] keinen Regelverstoß erkennen.".

Part 3 - activating

Activating is an action applying to one number and one thing.

Understand "tipp [number] in/auf [dativ] [something] ein/--" as activating.

Understand "gib [number] in/auf [dativ] [something] ein/--" as activating.

Understand "geb [number] in/auf [dativ] [something] ein/--" as activating.

The parser error internal rule response (D) is "Das [keypad] [des reader]s hat nur Zifferntasten.".

Check activating:

if the second noun is the reader or the second noun is the checkout:

now the second noun is the keypad;

if the second noun is not the keypad:

say "Auf [dem second noun] kann man keine PIN-Nummern eingeben." instead;

if the girocard is not in the reader:

say "Ohne eingesteckte EC-Karte ist das Lesegerät nicht sehr empfänglich für Tastatureingaben, musst du feststellen." instead;

if the number understood < 1000 or the number understood > 9999:

say "Deine PIN besteht aus vier Zahlen, nicht mehr und nicht weniger, da bist du dir ganz sicher. Ziemlich sicher jedenfalls." instead;

Carry out activating:

if the number understood is 1234 and the failures of the girocard is 0:

now the number understood is 1224;

say "Du tippst [number understood] in das [keypad] [des reader]s und hoffst, dass das deine PIN ist.[paragraph break]";

if the number understood is 1234:

say "Der Monitor reagiert mit 'Vielen Dank für ihren Einkauf!' und spuckt eine Quittung aus, die auf die Waage fällt.";

now the receipt is on the scale;

else:

say "Mist, falsche Nummer! Oder nur vertippt?";

increment the failures of the girocard.

Part 4 - jumping over

Jumping over is an action applying to one thing.

Understand "spring ueber/-- [something]" as jumping over.

Understand "huepf ueber/-- [something]" as jumping over.

Check jumping over:

say "Das ist doch jetzt Quatsch, oder?" instead.

Part 5 - dancing

Dancing is an action applying to nothing.

Understand "tanz" as dancing.

Carry out dancing:

leave the "dance" world saying "Das sieht ein bisschen bekloppt aus, wenn du tanzt, aber das ist dir egal. Wenn du Lust zu tanzen hast, dann tanzt du eben.[paragraph break][bracket]Siehe: https://youtu.be/wlZE5JaD4kU[close bracket]" and "Du bist noch voll am abhotten, als es wieder passiert.".

Part 6 - conjuring

Conjuring is an action applying to nothing.

Understand "xyzzy", "plugh" as conjuring.

Report conjuring:

leave the "spell" world saying "Du sprichst den alten Zauberspruch, teils aus Jux, teils aus Gewohnheit, ohne Erwartung, sozusagen 'Ergebnisoffen'." and "Sehr überrascht bist du allerding nicht, dass dann tatsächlich 'nur' das Phänomen eintritt.".

Part 7 - talking to

Talking to is an action applying to one thing.

Understand "red mit/zu [dativ] [something]" as talking to.

Check talking to:

if the noun is not a person:

say "Jetzt redest du schon mit [dem noun]!" instead.

Report talking to:

say "[Den noun] interessiert das nicht.".

Volume 5 - Yourself

Description of yourself is "Das Fass möchtest du heute lieber nicht aufmachen.".

Instead of attacking yourself, leave the "suicide" world saying "In diesem Augenblick wird dir klar, dass du keine Lust hast, dich weiter gängeln zu lassen. Nicht von der Gesellschaft, nicht vom Supermarkt, nicht von dummen Regeln, von nichts und niemandem.[paragraph break]Niemehr.[paragraph break]Und du weißt auch, wie du es anstellen willst!" and "Leider findest du nicht mehr heraus, ob es klappt oder nicht, denn schon wieder tritt das Phänomen auf.".

Instead of undressing yourself, leave the "nude" world saying "Als ob du Strippoker mit dir selbst spielst, entledigst du dich eines Kleidungsstückes nach dem anderen. Seltsamerweise hält dich auch [der employee] nicht davon ab. Schliesslich stehst du nackt da und es sieht, sagen wir mal, interessant aus." and "Interessieren tut sich niemand dafür, aber wenigsten kannst du das Phänomen damit triggern.".

Instead of smelling yourself, say "Hm, vermutlich sollten deine Klamotten mal wieder eine Waschmaschine von innen sehen.".

Instead of drilling yourself, say "Nach kurzer Evaluation gelangst du zur Einsicht, dass es in dir schon genug Löcher gibt und du keine weiteren benötigst.".

Volume 6 - Prolog & Status Line

When play begins:

say "Peinlich, peinlich... über ein halbes Jahr hattest du Nils[apostrophe] Bohrmaschine ausgeliehen. Schliesslich hat Nils angerufen und dir gesagt, dass er 'jetzt langsam mal die Bohrmaschine zurück' bräuchte [-] das 'langsam' mit Betonung auf dem 'sofort'.[paragraph break]Wie das halt so ist, hast du es in der ganzen Zeit nicht mal geschafft, deine Regale an die Wand zu schrauben. Und seine Bitte, dir auf dem Weg 'ein paar Sachen vom Supermarkt' mitzubringen konntest du natürlich schlecht ausschlagen...[paragraph break][paragraph break]";

now the right hand status line is "Gewicht: [total weight of things on the scale] kg";

now the left hand status line is "Summe: ¬ [shopping amount to 2 decimal places]";

Volume 7 - Das Selbstzahlergehege

The self-pay area is a room. "Vermutlich ist es nur der Brandschutzverordnung geschuldet, dass dieser Bereich nicht abgesichert ist, wie der Ausgang eines Untersuchungsgefängnisses: Lediglich die fragil wirkende Schranke im Süden hält dich davon ab, einfach aus dem Supermarkt zu spazieren. Auf der anderen Seite, im Norden des Geheges, geht es zurück in den Warenbreich des Supermarktes.".

Printed name of the self-pay area is "Selbstzahlergehege[n]".

Understand "selbstzahlergehege", "gehege" as self-pay area.

Instead of going nowhere in the self-pay area:

say "[The self-pay area] ist durch einen schulterhohen Zaun eingefasst, der dein Entkommen verhindert. Eine Öffnung gibt es nur im Norden, wo der Warenbereich liegt. Die Schranke im Süden muss erst mit einem Einkaufsbeleg geöffnet werden, bevor dich der Supermarkt in die Freiheit entlässt.".

Instead of going north in the self-pay area, say "Zurück in das Labyrinth? Nee, du hast alles, was du einkaufen wolltest.".

[Instead of entering in the self-pay area, try going north.]

Instead of going inside in the self-pay area, try going north.

Instead of going south in the self-pay area, try exiting.

Instead of exiting in the self-pay area:

if the barrier is closed:

say "Du läufst blind los und knallst gegen die gläserne Schranke. Autsch! Zusätzlich zum Schmerz muss du auch noch den mißbilligenden Blick [des employee] ertragen.";

else if nils is false:

if not all goods are carried by the player:

leave the "lost" world saying "Endlich bist du fertig hier und kannst den Supermarkt verlassen. In Gedanken bist du schon dabei, Nils seine Bohrmaschine zurück bringen und überlegst, was du heute noch machen willst." and "Dir fällt auf, dass du Sachen im Supermarkt liegen lassen hast, aber zu spät, denn wieder tritt das Phänomen auf.";

else if the girocard is not carried by the player:

leave the "card" world saying "Endlich bist du fertig hier und kannst den Supermarkt verlassen. In Gedanken bist du schon dabei, Nils seine Bohrmaschine zurück bringen und überlegst, was du heute noch machen willst." and "Dir fällt auf, dass du deine EC-Karte im Supermarkt vergessen hast, aber zu spät, denn wieder tritt das Phänomen auf.";

else if the deposit is not recorded:

leave the "deposit" world saying "Endlich bist du fertig hier und kannst den Supermarkt verlassen. In Gedanken bist du schon dabei, Nils seine Bohrmaschine zurück bringen und überlegst, was du heute noch machen willst." and "Dir fällt auf das du den Pfandbon nicht eingelöst hast, aber zu spät, denn wieder tritt das Phänomen auf.";

else if the shopping amount > -8.12:

leave the "plus" world saying "Endlich bist du fertig hier und kannst den Supermarkt verlassen. In Gedanken bist du schon dabei, Nils seine Bohrmaschine zurück bringen und überlegst, was du heute noch machen willst." and "Du fragst dich, ob du im Supermarkt nicht zu viel bezahlt hast, aber zu spät, denn wieder tritt das Phänomen auf.";

else if the shopping amount is -8.62:

leave the "banana" world saying "Endlich bist du fertig hier und kannst den Supermarkt verlassen. In Gedanken bist du schon dabei, Nils seine Bohrmaschine zurück bringen und überlegst, was du heute noch machen willst." and "Du freust dich über die ergaunerte Banane, aber nicht lange, denn wieder tritt das Phänomen auf.";

[else if the shopping amount is -8.12:]

else:

leave the "exit" world saying "Endlich bist du fertig hier und kannst den Supermarkt verlassen. In Gedanken bist du schon dabei, Nils seine Bohrmaschine zurück bringen und überlegst, was du heute noch machen willst." and "Du wirst aus deinen Träumen gerissen, denn wieder tritt das Phänomen auf." instead;

else if nils is true:

say "Endlich kommst du aus diesem verfluchten Supermarkt raus. Hoffentlich hast du noch genug Zeit, um die Regale anzuschrauben, bevor... hm, es lag dir grad noch auf der Zunge, wer heute bei dir vorbei kommen will, um sich die Bohrmaschine auszuleihen. Wer war es bloß?";

end the story finally.

Instead of dropping something in the self-pay area:

say "'[if the noun is a good]Bringen sie [der noun] bitte zurück, wenn sie [*der*] nicht haben wollen!' weist dich [the employee] zurecht. 'Aber ich will [*der*] ja haben[else]Abfälle entsorgen sie bitte hinter dem Kassenbereich!' maßregelt dich [the employee]. 'Ok[end if].' erwiderst du lahm und balancierst weiter die ganzen Sachen in deinen Händen[first time]. Hättest du dir doch einen Korb beim Reingehen genommen[only].".

Book 1 - supermarktet (Warenbereich des Supermarktes)

The supermarket is a backdrop in the self-pay area.

Printed name of the supermarket is "Warenbereich des Supermarktes[m]".

Understand "waren/warenbereich", "supermarkt", "regal/regale", "kuehltruhe/kuehltruhen" as supermarket.

Description of the supermarket is "Der Warenbereich des Supermarktes liegt nördlich des Selbstzahlergeheges. Man kann ihn gut von hier aus sehen, mit seinen Regalen, Kühltruhen und... tja, eigentlich gibt es dort nichts weiter als Regale und Kühltruhen.".

Book 2 - entrance (Eingangsbereich)

The entrance is a backdrop in the self-pay area.

Printed name of the entrance is "Eingangsbereich des Supermarktes[m]".

Understand "eingang/ausgang", "eingangsbereich" as entrance.

Description of the entrance is "Der Ein- und Ausgang des Supermarktes befindet sich südlich von dir hinter Schranke des Selbstzahlergeheges. Dort sieht man ineinander geschobene Einkaufswagen, sowie Paletten mit Blumenerde und andere saisonale Quatschprodukte.".

Book 3 - barrier (Schranke)

The barrier is a scenery door.

The barrier is south of the self-pay area.

The barrier is closed and not openable.

The barrier is able to scan.

Printed name of the barrier is "Schranke[f]".

Understand "schranke", "pforte/pforten", "ausgang" as barrier.

Description of the barrier is "Die Schranke besteht aus zwei unauffälligen Glasflügeln, die sich nach außen öffnen, wenn man seinen Einkaufsbeleg auf den kleinen Scanner legt, der in die Spitze der Halterung integriert ist[first time]. Falls man das vergisst, bricht man sich das Genick, wie ein kleiner Vogel, der gegen eine Glasscheibe fliegt[only].".

Instead of examining the open barrier, say "Die Schranke ist offen, du kannst den Supermarkt verlassen."

Instead of going through the barrier, try exiting.

Instead of entering the barrier, try exiting.

Instead of opening the closed barrier, say "Du versuchst vorsichtig die Schranke aufzudrücken, aber [the employee] belehrt dich: 'Die Schranke geht auf, wenn sie da ihre Quittung einscannen!'"

Instead of opening the open barrier, say "Die Schranke ist bereits offen."

Instead of scanning something with the barrier, try scanning the noun with the camera.

Instead of jumping over the open barrier, say "Nicht nötig, die Schranke ist offen.".

Instead of jumping over the closed barrier, leave the "jump" world saying "Mit einer Mischung aus springen und klettern schaffst du es über die Schranke und entkommst so aus dem Selbstzahlergehege." and "Unabhängig jeglicher juristischer Einordnung deiner Flucht ist deine Freude aber nur von sehr kurzer Dauer, denn schon wieder tritt dieses Phänomen auf.".

Instead of climbing the barrier, try jumping over the barrier.

Instead of unlocking the barrier with the receipt, try scanning the receipt with the camera.

Instead of unlocking the camera with the receipt, try scanning the receipt with the camera.

Part 1 - camera (Belegscanner)

The camera is part of the barrier. The camera is able to scan.

Printed name of the camera is "klein[^] Kamera[f]".

Understand "klein", "kamera", "beleg-scanner", "belegscanner" as camera.

Description of the camera is "Auf der Spitze einer glänzend polierten Edelstahlstange sitzt eine kleiner Kamera, der man seinen Einkaufsbeleg zeigen soll, damit sich die Schranke öffnet und man wieder in die Freiheit entkommen kann[first time]. Du fragst dich, warum [the employee] nicht einfach an diese Seite gestellt wird, und das Schranken-Kamera-Ensemble auf dem Schrottplatz entsorgt wird. Vermutlich soll [er] aber irgendwann eingespart werden; hoffentlich wird [er] dann nicht recycelt[only].".

Instead of putting something on the camera, try scanning the noun with the camera.

Check scanning something with the camera:

if the noun is not scannable:

say "[The noun] hat keinen Barcode. Die [camera] kann also nichts damit anfangen und [der employee] schaut dich [one of][or]auch schon wieder[stopping] böse an." instead;

if the noun is not the receipt:

say "Diese Kamera ist nur für deine Quittung gedacht und reagiert nicht auf andere Barcodes." instead.

Check scanning the receipt with the camera:

if the barrier is open:

say "Du musst die Quittung nicht noch mal vorzeigen, die Schranke ist schon offen." instead.

Carry out scanning the receipt with the camera:

say "Du hältst die Quittung vor die Kamera und die Schranke geht auf.";

now the barrier is open.

Book 4 - checkout (Selbstbedienungskasse)

The checkout is fixed in place in the self-pay area.

The checkout is able to scan.

Printed name of the checkout is "Selbstzahlerkasse[f]".

Understand "selbstzahlerkasse", "selbstbedienungskasse", "kasse" as checkout.

Description of the checkout is "[first time]'Selbstzahlerkasse' ist ein besonders schöner Euphemismus [-] als ob an der normalen Kasse jemand anders für einen zahlen würde. [only]Das Ding besteht aus drei Komponenten: In hüfthöhe die Waage, die gleichzeitig Barcodes einscannen kann. Darüber der Monitor, auf dem man herumdrücken kann und daneben der EC-Karten-Leser[first time], damit du den ganzen Krempel, den du aus den Regalen gepflückt hast, am Ende bezahlen kannst [-] selbst bezahlen, wie gesagt[only].".

Instead of putting something on the checkout, try putting the noun on the scale.

Instead of scanning something with the checkout, try scanning the noun with the scale.

Instead of climbing the checkout, leave the "onto" world saying "Was für ein Zirkus soll das hier eigentlich sein? Wenn du dich schon zum Affen machen lassen musst, dann aber richtig! Du kletterst also auf die Kasse und trommelst dir auf die Brust wie Kunde Kong." and "So weit so gut, aber (natürlich?) tritt wieder das Phänomen auf.".

Instead of attacking the checkout, leave the "destroy" world saying "Macht kaputt, was euch kaputt macht! Mit der Bohrmaschine wirst du es doch wohl schaffen, die Kasse in ihre recyclebaren Einzelteile zu zerlegen, bevor dich [der employee] ausbremsen kann, oder?" and "Nein, tust du nicht, aber das liegt nicht an [dem employee], sondern am Phänomen, das wieder auftritt.".

Instead of drilling the checkout, try attacking the checkout.

Part 1 - monitor (Bildschirm)

The monitor is part of the checkout.

Printed name of the monitor is "Bildschirm[m]".

Understand "bildschirm", "display", "touchscreen" as monitor.

Description of the monitor is "Auf dem Monitor sind die Informationen zu deinem Einkauf zu sehen. Außerdem gibt es vier 'Tasten': 'Backwaren', 'Obst', 'Gemüse' und 'Bezahlen'. Oben links steht das Gewicht aller Dinge, die auf der Waage liegen ([total weight of things on the scale] kg) und oben rechts der Gesamtbetrag deines Einkaufs (¬ [shopping amount to 2 decimal places]). ".

Instead of touching the monitor, say "Ja, es ist ein Touchscreen, aber du musst schon wissen, auf welche 'Taste' du da drücken willst.".

Instead of pushing the monitor, try touching the monitor.

Chapter 1 - buttons

Section 1 - baked button

The baked button is part of the monitor.

Printed name of the baked button is "Backwaren-Taste[f]".

Understand "auf/-- die/-- backwaren/backwaren-taste", "taste" as baked button.

Instead of touching the baked button, try pushing the baked button.

Instead of pushing the baked button:

say "Du drückst auf die Backwaren-Taste und [one of]schon öffnet sich eine Seite mit Fotos unterschiedlicher Backwaren. Stellt sich raus, es gibt fast hundert verschiedene Backwaren und es sind fünf Seiten mit Fotos. Irgendwann findest du endlich dein dummes Weizenbrötchen und du bongst es[or]du bongst das Brötchen nochmal[stopping] ein.";

now the bun is recorded;

add the price of the bun.

Section 2 - fruit button

The fruit button is part of the monitor.

Printed name of the fruit button is "Obst-Taste[f]".

Understand "auf/-- die/-- obst/obst-taste", "taste" as fruit button.

Instead of touching the fruit button, try pushing the fruit button.

Instead of pushing the fruit button:

let TW be the total weight of things on the scale;

if the bananas are recorded:

say "Die Bananen hast du doch schon abgewogen.";

[say "Die Bananen hast du zwar schon abgewogen, aber doppelt hält besser, oder?";

add TW * price of the bananas;]

else if TW is less than the weight of the bananas:

say "'Brauchen sie Hilfe beim Abwiegen?' bölkt [the employee] unfreundlich zu dir rüber, bevor du auf die nächste Taste drücken kannst (die mit dem Bananenfoto). Am besten, du legst erst mal die Ware auf die Waage.";

else:

say "Du drückst auf die Obst-Taste, dann auf die Bananen-Taste und die Bananen sind gebongt[if TW > the weight of the bananas]. Das neben den Bananen noch andere Sachen auf der Waage liegen treibt den Preis natürlich etwas in die Höhe, aber das scheint [den employee] nicht zu stören[end if].";

now the bananas are recorded;

add TW * price of the bananas.

Section 3 - vegetable button

The vegetable button is part of the monitor.

Printed name of the vegetable button is "Gemüse-Taste[f]".

Understand "auf/-- die/-- gemuese/gemuese-taste", "taste" as vegetable button.

Instead of touching the vegetable button, try pushing the vegetable button.

Instead of pushing the vegetable button, say "Du hast doch gar kein Gemüse gekauft.".

Section 4 - pay button

The pay button is part of the monitor.

The pay button can be ready. The pay button is not ready.

Printed name of the pay button is "Bezahlen-Taste[f]".

Understand "auf/-- den/die/-- zahlen/bezahlen/bezahl/bezahlen-taste", "taste" as pay button.

Instead of touching the pay button, try pushing the pay button.

Check pushing the pay button:

if some goods are not recorded:

say "[The employee] sieht alles und fällt dich an: 'Sie haben noch nicht alle Waren erfasst!'" instead;

if the pay button is ready:

say "Nochmal auf die Taste zu drücken bringt nicht." instead.

Carry out pushing the pay button:

now the pay button is ready.

After pushing the pay button:

say "Du drückst auf 'Bezahlen' und der Monitor erwidert: 'Bitte EC-Karte in den Kartenleser einführen.' Irgendwie klingt das anzüglich.".

Part 2 - scale (Waage)

The scale is part of the checkout. The scale is a supporter. The scale is able to scan.

Printed name of the scale is "Waage[f]".

Understand "warenscanner", "waage mit/-- scanner/--", "scanner" as scale.

Description of the scale is "Bei diesen Waagen mit integriertem Scanner weiß man nicht genau, ob man sie nun Scanner oder Waage nennen soll. Eigentlich verdienen sie einen eigenen Namen, so verbreitet wie sie inzwischen sind und bestimmt haben sie auch einen, aber der ist sicher lang, sperrig und textadventureunfreundlich.".

Carry out scanning something with the scale:

say "Du ziehst [the noun] über den Scanner in der Waage und die Kasse piepst einmal. Auf dem Monitor wird [er][if the noun is recorded] ein weiteres mal[end if] zur Liste der Waren hinzugefügt.";

now the noun is recorded;

add price of the noun.

Instead of scanning the receipt with the scale:

say "Die Kasse kann mit der Quittung nix anfangen, die ist für die Schranke, sozusagen deine Entlassungspapiere, damit du hier raus darfst. Und für deine Unterlagen, wenn du gerne Buch führst.".

Does the player mean scanning something with the camera:

if the noun is the receipt:

it is very likely;

else:

it is very unlikely.

Part 3 - reader (Kartenleser)

The reader is part of the checkout. The reader is a container.

Printed name of the reader is "Kartenleser[m]".

Understand "kleiner/kleinen/kleines/-- ec/-- kartenleser/leser/lesegeraet", "schlitz" as reader.

Description of the reader is "Ein kleiner EC-Kartenleser mit einem Schlitz zum Einstecken der Karte und einem Tastenfeld.".

Check inserting something into the reader:

if the noun is listed in {deposit, note, receipt}, say "'Wenn sie den Kartenleser manipulieren, gibt es hier ganz schnell Hausverbot!' sagt [the employee] und seine Stimmlage kippt dabei in Richgung Kreissäge.[paragraph break]'Hätte aber klappen können.' murmelst du leise zu dir selbst." instead;

if the noun is not the girocard, say "Der flache Schlitz des Kartenlesers ist zu klein für [the noun]." instead;

if the pay button is not ready, say "'Sie müssen erst auf Bezahlen drücken.' weiß [the employee] bescheid[if not all goods are recorded] und fügt hinzu: 'Aber vorher müssen sie noch ihren restlichen Einkauf erfasst haben.'[else].[end if]" instead;

if not all goods are recorded, say "'Sie wollen doch wohl nicht bezahlen, bevor sie alle Waren erfasst haben?' brüllt dir [the employee] entgegen, dass deine Haare anfangen zu flattern." instead.

After inserting the girocard into the reader, say "Du schiebst die EC-Karte in den Schlitz des Kartenlesers. Jetzt nur noch die PIN eingeben [-] ganz entspannt, nicht nervös werden.".

Chapter 1 - keypad

The keypad is part of the reader.

Printed name of the keypad is "Tastenfeld[n]".

Understand "tastenfeld", "tasten" as keypad.

Description of the keypad is "Ein kleines Tastenfeld mit den Zahlen 1 bis 9, sowie der Null.".

Book 5 - drill (Nils' Bohrmaschine)

The drill is carried by the player. The drill has weight 0.852.

Printed name of the drill is "Bohrmaschine[f]".

Understand "bohrer", "bohrmaschine", "maschine", "schrauber", "akkuschrauber" as drill.

Description of the drill is "Das ist Nils[apostrophe] Bohrmaschine. Besonders groß ist sie nicht[first time]. Aber Nils ist ja auch Feinmechaniker.[paragraph break]'Feinmechaniker, ist das nicht total aus der Zeit gefallen?' hast du ihn mal gefragt.[line break]'Deswegen mache ich ja die Umschulung zum Quantenmechaniker.' hat er geantwortet. Nils halt.[paragraph break]Tatsächlich bist du ganz froh, die Bohrmaschine wieder loszuwerden. Irgendwas ist nicht in Ordnung damit. Wie hat Nils sie beim Ausleihen bezeichnet? Als 'MacGuffin'? Als 'Tschechows Gewehr'? Oder als 'Schrödingers Katze'? Kaputt ist die Bohrmaschine zwar nicht, aber seitdem du sie hast, kriegst du nichts mehr gebacken: Weder Regale anschrauben, noch Uni [-] dein ganzes Leben fühlt sich einfach nur noch unrealistisch an[only].".

Instead of smelling the drill, say "Die Bohrmaschine riecht nach verbranntem Plastik.".

Instead of drilling the drill, leave the "drill" world saying "Eigentlich geht das nicht. Aber irgendwie schaffst du es trotzdem und verwandelst damit deine Welt in ein Gemälde von M. C. Escher." and "Du schwelgst in dem seltsamen Gefühl und wartest darauf, dass das Phänomen eintritt, aber es kommt nicht.[paragraph break]Ah, doch, da ist es!".

Instead of switching on the drill, say "Du lässt die Bohrmaschine einmal kurz aufheulen [-] Weijoouu! [-] das ist fast so cool wie Mofa fahren!".

Instead of switching off the drill, say "Ist doch schon aus.".

Book 6 - note (Einkaufszettel)

The note is carried by the player.

Printed name of the note is "Einkaufszettel[m]".

Understand "einkaufszettel", "notiz", "zettel" as note.

Description of the note is "Das Gekrakel auf dem Zettel ist nicht zu entziffern, aber du kannst dich noch erinnern, was du da notiert hast: Mineralwasser, Bananen, Brötchen.".

Instead of smelling the note, say "Der Zettel riecht nach Krankenhaus.".

Instead of eating the note:

say "Mhh, lecker Zettel.";

now the note is nowhere.

Book 7 - bun (Brötchen)

The bun is a good. It is carried by the player.

The bun has weight 0.037. The bun has price 0.49.

Printed name of the bun is "Brötchen[n]".

Understand "broetchen", "schrippe", "rundstueck", "semmel", "wecke" as bun.

Description of the bun is "Ein durch und durch standardisiertes Weizenbrötchen[first time]. Nix mit Käse oder Krümeln drauf, weder Dinkel noch Bio und auch nicht gelaugt. Nils hat gesagt, du sollst Brötchen mitbringen und du kannst dich nicht mehr erinnern, ob da ein 'ein' vor dem Brötchen war, oder nicht. Wird schon passen[only].".

Instead of smelling the bun, say "[if nils is false]Das Brötchen riecht wie nasser Karton. Vermutlich schmeckt es aber auch so[else]Das Brötchen riecht noch nach Backofen[end if].".

Instead of eating the bun, say "[if nils is false]Du kannst doch Nils kein angeknabbertes Brötchen mitbringen[else]Nein, das wirst du dir zuhause schön mit Frischkäse und Kresse zurecht machen und dann essen[end if]!"

Book 8 - soda (Mineralwasser)

The soda is a good. The soda is carried by the player. The soda is scannable.

The soda has weight 1.013. The soda has price 1.14.

Printed name of the soda is "Flasche Mineralwasser[f]".

The grammatical gender of the soda is feminine gender.

Understand "wasser", "mineralwasser", "flasche", "sprudel" as soda.

Description of the soda is "Trinkwasser in einer Plastikflasche. Unter dem geistlosen Produktnamen steht 'Classic', was bedeutet, dass im Sprudelwasser tatsächlich Sprudel ist.".

Understand "trink aus [something]" as drinking.

Instead of opening the soda, try drinking the soda.

Instead of drinking the soda, say "Du machst die Flasche auf und trinkst [one of][or]nochmal [stopping]daraus [-] aber nur einen kleinen Schluck, das Wasser ist ja für [if nils is false]Nils[else]später[end if].".

Instead of smelling the soda, say "Sowohl die Flasche als auch das Wasser darin riechen ein bisschen nach Dosenmais.".

Instead of showing the soda to the scale:

say "Du ziehst die Flasche über den Scanner und das Gerät piept einmal. Auf dem Monitor wird das Mineralwasser zu deinen Einkäufen hinzugefügt.".

Book 9 - bananas (Bananen)

Some bananas are a good. They are carried by the player.

The bananas have weight 0.741. The bananas have price 3.49.

Printed name of the bananas is "Bananen[p]".

Understand "banane/bananen" as bananas.

Description of the bananas is "Ein paar zusammenhängende Bananen, die sich ähnlich Schrödingers Katze gleichzeitig in den Zuständen 'unreif / zu fest' und 'überreif / zu matschig' befinden.".

Instead of smelling the bananas, say "Die Bananen riechen ein bisschen nach Nagellack.".

Instead of eating the bananas for the first time:

say "Du pellst eine Banane aus ihrer Schale und schiebst sie dir in den Mund. [The employee] schaut zu dir rüber und ruft: 'Haben sie die überhaupt schon abgewogen?'[paragraph break]Nickend und mit vollen Backen kauend erwiderst du: 'Mäh.'. [Er] runzelt skeptisch die Stirn, scheint aber zufrieden gestellt.";

now the weight of the bananas is 0.598.

Instead of eating the bananas for more than the first time:

say "Aus Angst, [if nils is false]sowohl mit dem Servicemitarbeiter als auch mit Nils Ärger[else]Ärger mit der Servicemitarbeiterin[end if] zu bekommen, traust du dich nicht, eine weitere Banane zu essen.".

Book 10 - deposit (Pfandbon)

The deposit is carried by the player.

The deposit is scannable.

The deposit can be recorded.

The deposit has a real number called price.

The deposit has price -12.34.

Printed name of the deposit is "Pfandbon[m]".

Understand "bon", "pfandbon", "flaschenpfand", "pfand" as deposit.

Description of the deposit is "Bei dieser Gelegenheit hast du gleich mal deine ganze Pfandflaschensammlung entsorgt und es ist gut was zusammen gekommen: ¬12,34 steht da als Summe.[paragraph break]Witzig, meine EC-Karten-PIN, denkst du dir.".

Instead of scanning the deposit with the scale when the deposit is recorded:

say "Du versuchst, den Pfandbon noch einmal einzuscannen, aber die Kasse durchschaut deinen billigen Trick[first time] und verweigert den begehrten Piepser. Dafür schaut [the employee] mit einem Blick zu dir rüber, der Clint Eastwood zur Ehre gereicht hätte[only].".

Instead of smelling the deposit, say "Der Pfandbon riecht ein bisschen nach Erdbeeren.".

Book 11 - girocard (EC-Karte)

The girocard is carried by the player. The girocard has weight 0.004.

The girocard has a number called failures.

Printed name of the girocard is "EC-Karte[f]".

Understand "karte", "ec", "ec-karte" as girocard.

Description of the girocard is "Deine EC-Karte von der Sparkasse. Beim Bezahlen hast du immer Angst, vor Aufregung deine PIN zu vergessen. Und das macht dich dann so nervös, dass dir vor Aufregung deine PIN nicht mehr einfällt.".

Instead of smelling the girocard, say "Die EC-Karte riecht nach Bananen.".

Book 12 - receipt (Quittung)

The receipt is nowhere. The receipt is scannable.

Printed name of the receipt is "Quittung[f]".

Understand "quittung", "kassenzettel", "barcode" as receipt.

Description of the receipt is "Ein vermutlich giftiger Kassenzettel, der belegt, dass du irgendwas bezahlt hast. Unten ist ein Barcode abgebildet.".

Instead of smelling the receipt, say "Die Quittung riecht nach Bisphenol.".

Book 13 - portal

The limbo is a room.

The portal is nowhere. It is an open enterable container. The portal is fixed in place.

Printed name of the portal is "Dimensionstor[n]".

Understand "tor", "dimensionstor", "rahmen" as portal.

Description of the portal is "Das Portal ist groß wie eine Tür, aber der Rahmen ist nicht rechtwinklig, sondern oval und besteht aus flimmerndem hellblauen Licht. In den Rahmen spannt sich eine dunkelblaue Membran, durch die man sicher hindurch gehen kann. Ganz offensichtlich handelt es sich hier um ein Dimensionstor, ein Portal in eine Parallelwelt.".

The membrane is part of the portal.

Printed name of the membrane is "Membran[f]".

Understand "blaue/dunkelblaue/-- membran", "parallelwelt" as membrane.

Description of the membrane is "Die Membran im Rahmen des Portals ist dunkelblau und wabert leicht hin und her, wie Wasser in einer Badewanne. Sie wirkt transparent, aber auch wenn du genau hinschaust, kannst du nicht erkennen, was sich dahinter befindet.".

Rule for printing the name of the portal:

omit contents in listing;

continue the action.

Instead of inserting something into the portal:

say "Du wirfst [*den*] [noun] in das Dimensionstor und [er] verschwindet darin.";

now the noun is in the limbo.

Instead of entering the portal:

now nils is true;

now the description of yourself is "Du bist Nils, wer solltest du sonst sein?";

now the description of the drill is "Das ist deine Bohrmaschine. Besonders groß ist sie nicht, aber wie du sie so anschaust, fragst du dich, warum du sie mit in den Supermarkt genommen hast. Als hättest du hier nicht schon genug Zeug in den Händen.";

now the description of the bun is "Ein leckeres Weizenbrötchen, so wie du es magst!";

re-genderise the employee to "Servicemitarbeiterin[f]";

leave the "portal" world saying "Es scheint dir völlig selbstverständlich, durch das Portal zu gehen [-] was soll schon schief gehen? Andere Fragen, die du dir ebenfalls nicht stellst sind: Was macht das hier? Woher kommt es? Wie ist das befestigt? Ist das überhaupt vom TÜV abgesegnet?" and "Du gehst einfach hindurch und bist nicht verwundert, dass es sich wie das Phänomen anfühlt.".

Volume 8 - employee (Der Servicemitarbeiter)

The employee is a person in the self-pay area.

Printed name of the employee is "Servicemitarbeiter[-s][m]".

Understand "mann", "typ", "aufpasser", "arbeiter", "mitarbeiter", "servicemitarbeiter" as employee when nils is false.

Understand "frau", "tussi", "aufpasserin", "arbeiterin", "mitarbeiterin", "servicemitarbeiterin" as employee when nils is true.

Description of the employee is "Du schaust zu [dem employee] rüber und [er] schaut demonstrativ zur Seite[first time]. '[employee]' ist natürlich ein Euphemismus. Weder von Service noch von Arbeit kann hier die Rede sein. Den Job gibt es nur, weil die Supermarktbetreiber sich nicht trauen, den Laden komplett unbeaufsichtigt zu lassen; vermutlich zu recht.[paragraph break][Der employee] steht lustlos und gelangweilt in [seiner] Supermarktuniform da, aber bei dem Job kann man auch nur lustlos und gelangweilt rumstehen und du fragst dich, warum [er] nicht auf [if nils is false]seinem[else]ihrem[end if] Handy spielt. Aber man soll ja nicht von sich auf andere schließen[only].".

To say Mann:

if nils is false:

say "Mann";

else:

say "Frau".

The uniform is worn by the employee.

Printed name of the uniform is "Supermarktuniform[f]".

Understand "supermarktuniform", "kleidung", "saum", "saeume" as uniform.

Description of the uniform is "Einst erstrahlte die Uniform in kräftigem Blau und hatte knallrosa Säume, doch nun wirkt sie blass und verwaschen.".

Instead of taking the uniform, try undressing the employee.

Book 1 - smelling

Instead of smelling the employee, say "Du traust dich nicht, an [*dem* employee] [Mann] zu riechen.".

Book 2 - talking

Instead of telling the employee about something:

say "Das alles erzählst du [*dem* employee] [Mann], aber [er] schaut irgendwo anders hin und du weisst nicht, ob [er] dir überhaupt zuhört. Am Ende blickt [er] dich an und fragt: 'Und? Ich verstehe nur [italic type]Bahnhof und [topic understood][roman type].'".

Instead of asking the employee about something:

say "Du sprichst [*den* employee] [Mann] darauf an, aber [er] zuckt noch nicht mal mit den Schultern: '[topic understood in sentence case]? Keene Ahnung.'".

Instead of answering the employee that something:

say "[Der employee] sagt: '[topic understood in sentence case] was?'.[paragraph break]Dann schaut [er] auch schon wieder woanders hin.".

[Instead of asking the employee about something, try telling the noun about it.

Instead of answering the employee that something, try telling the noun about it.]

Book 3 - touching

Instead of touching the employee, say "Du stupst [*den* employee] [Mann] an, um zu sehen, ob [er] wirklich ein echter Mensch ist oder nur ein Animatronic. 'Hey, was soll das?' blafft [er] dich zurückweichend an. Es wirkt authentisch menschlich, aber ganz sicher bist du dir immer noch nicht.".

Book 4 - attacking

Instead of attacking the employee:

leave the "kill" world saying "Du machst dich zum Angriff bereit, holtst aus und versenkst deine Faust mit aller Kraft in der Magengrube [des employee]. Aber nur in deiner Phantasie, denn [er] antizipiert dein Vorhaben und hat offenbar einen hohen Dan-Grad in einer dir unbekannten, aber sehr effektiven Kampfsportart. Innerhalb von wenigen Sekunden liegst du mit der Backe auf dem kalten Fussboden und an einigen Körperteilen breiten sich starke Schmerzen aus, vermutlich die Stellen, an denen du getroffen wurdest." and "[Der employee] hat dich besiegt. Aber zum Glück musst du nicht lange leiden, denn wieder tritt das Phänomen auf.".

Book 5 - kissing

Instead of kissing the employee, leave the "kiss" world saying "Ganz offensichtlich bist du nicht der Typ [des employee]. Denn als du mit ausgestreckten Händen und gespitzten Lippen auf [ihn] losgehst, sinkt [er] keineswegs in deine Arme. Mit ein paar sehr geschickten Handgriffen schickt [er] dich abwärts und du küsst den Boden." and "Lange liegst du nicht dort, denn wieder tritt das Phänomen auf.".

Book 6 - undressing

Instead of undressing the employee, leave the "strip" world saying "Liegt es an deinem Blick? Oder bist du hier schon bekannt? [Der employee] kann offenbar deine Gedanken lesen und bevor du [ihn] auch nur berühren kannst, legt [er] dich mit ein paar schnellen Griffen auf den Boden." and "Zu deinem Glück musst du das Eintreffen der Polizei nicht mehr erleben, denn (mal) wieder tritt das Phänomen auf.".

Book 7 - giving something

Instead of showing something to the employee, try giving the noun to the employee.

Instead of giving something to the employee:

if the noun is a good:

say "[Der employee] wehrt [the noun] mit der Hand ab: 'Die Waren müssen sie an der Selbstzahlerkasse erfassen.'";

else if the noun is the drill:

say "[Der employee] schüttelt den Kopf: 'Sowas führen wir hier nicht, das müssen sie woanders entsorgen.'";

else if the noun is the deposit:

say "Routiniert schnappt [der employee] sich deinen Pfandbon und steckt ihn ein. [Er] nickt und sagt: 'Nett von ihnen', dann schaut [er] wieder weg von dir.";

now the deposit is nowhere;

else if the noun is the girocard:

say "'Die müssen sie in den Kartenleser an der Selbstzahlerkasse stecken und dann ihre PIN eingeben. Aber natürlich erst, wenn sie alle Waren erfasst haben.' sagt [der employee]. [Er] kneift die Augen zusammen und schaut dich an, als würdest du hier regelmäßig etwas mitgehen lassen.";

else if the noun is the note:

say "[Der employee] zeigt zum Ausgang und sagt: 'Hinter dem Kassenbereich gibt es Müllbehälter für Plastik, Kartons und Restmüll.'[paragraph break]Nach einer Pause fügt [er] hinzu: 'Den Zettel können sie in den Schlitz für Kartons werfen.' und du fragst dich unweigerlich, ob du so aussiehst, als wenn dir das nicht klar wäre.";

else if the noun is the receipt:

say "Wortlos hält [der employee] dir die flache Hand entgegen und zeigt dann auf die Kamera in der Schranke.";

else:

say "[Der employee] schaut zur Seite und tut so, als würde [er] dich nicht wahrnehmen.".

Book 8 - drilling

Instead of drilling the employee, say "Das wolltest du doch wohl nicht wirklich probieren, oder?[paragraph break]ODER???".

Volume 9 - Parallel Worlds

loop is a number that varies.

worlds_found is a list of text that varies.

To leave the (event - a text) world saying (primer - text) and (particle - text):

if there is a world corresponding to an id of event in the Table of Parallel Worlds:

choose row with an id of event in the Table of Parallel Worlds;

let parallel_world_text be the world entry;

let parallel_world_count be 0;

if there is a count entry:

now parallel_world_count is the count entry;

now the count entry is parallel_world_count + 1;

else:

blank out the world entry;

say "[primer][paragraph break]";

if loop is 0:

say "Plötzlich versinkt alles um dich herum in blauem Licht. 'Hä?' denkst du dir und schon fängt dein ganzer Körper an zu kribbeln und du denkst, du wirst gleich ohnmächtig. Aber da merkst du, das deine Beine laufen und du gerade mit deinem Einkauf in den Kassenbereich des Supermarktes marschierst...";

choose a blank row in Table of Encounters;

now event entry is "Eine Frau in rotem Kleid schwebt herein und du fragst dich, in welchem Film du gelandet bist. Als du dich das zweite Mal zu ihr umsiehst, ist sie aber nicht mehr zu entdecken. Seltsam...";

choose a blank row in Table of Encounters;

now event entry is "Drei verdammt echt aussehende Stormtrooper kommen herein, um ihre Tiefkühlpizzen zu scannen. Als sie nach draußen marschieren fragst du dich, ob in der Nähe eine Cosplay Convention stattfindet, oder tatsächlich ein imperialer Sternenkreuzer vor der Tür ankert.";

choose a blank row in Table of Encounters;

now event entry is "Jemand in einem Kaninchenkostüm kommt herein und scannt Eier. Langsam wundert dich hier gar nichts mehr. Schon hoppelt er hinaus.";

else:

say "[particle] Das war also [if parallel_world_count > 0]mal wieder [end if]die Parallelwelt, in der du [parallel_world_text]. Alles wird in helles blaues Licht getaucht, es kribbelt in deinem Körper, als du davon erfasst wirst und im nächsten Augenblick bist du dabei, auf ein Neues den Kassenbereich des Supermarktes zu betreten.";

if nils is true, say "[first time][line break]Aber irgendwas ist diesmal anders. Du weißt nur nicht, was.[only][paragraph break][paragraph break]Peinlich, peinlich... du hast ganz vergessen, wer sich deine Bohrmaschine ausleihen will. Nur, das sie heute abgeholt werden soll, das weißt du noch. Und das du vorher noch deine Regale anschrauben musst.[paragraph break]Aber bevor du damit anfangen kannst, bauchst du erstmal was zum Frühstücken. Also bist du rüber zum Supermarkt, um ein bisschen was einzukaufen.";

increment loop;

say "[paragraph break][paragraph break][banner text]";

[add parallel_world_text to worlds_found;]

reset the world;

else:

say "Ein ausgeprägtes Déjà-vu hält dich davon ab.".

Table of Parallel Worlds

id count world

"exit" 0 "ganz normal den Supermarkt verlässt"

"deposit" 0 "den Pfandbon nicht eingelöst hast"

"banana" 0 "den Supermarkt um eine Banane betrügst"

"card" 0 "deine EC-Karte im Supermarkt verlierst"

"plus" 0 "zuviele Sachen einbongst und zuviel bezahlst"

"lost" 0 "vergisst, deinen ganzen Einkauf mitzunehmen"

"kiss" -- "versuchst, [den employee] zu küssen"

"kill" -- "versuchst, [den employee] anzugreifen"

"nude" -- "dich im Supermarkt ausziehst"

"strip" -- "versuchst, [den employee] auszuziehen"

"onto" -- "auf die Selbstzahlerkasse kletterst"

"dance" -- "einen peinlichen Tanz im Supermarkt aufführst"

"jump" -- "über die Absperrung kletterst, um dich davon zu machen"

"destroy" -- "die Selbstzahlerkasse zerstören willst"

"suicide" -- "dich lieber umbringst, als deinen Einkauf zu bezahlen"

"portal" -- "durch ein Parallelweltportal gehst"

"drill" -- "es tatsächlich schaffst, mit der Bohrmaschine in sie selbst zu bohren"

"spell" -- "alte Zaubersprüche aufsagst"

To reset the world:

now all goods are not recorded;

now the deposit is not recorded;

now the pay button is not ready;

now the shopping amount is 0.0;

now the failures of the girocard is 0;

now the weight of the bananas is 0.741;

now the receipt is nowhere;

now the barrier is closed;

now the portal is nowhere;

repeat with item running through {bananas, bun, deposit, drill, girocard, note, soda}:

if the item is in the limbo:

now the item is in the self-pay area;

else:

now the player carries the item;

move player to self-pay area.

Volume 10 - Encounters

Every turn:

if a random chance of 1 in 6 succeeds and the Table of Encounters is non-empty:

choose a random row in the Table of Encounters;

say "[event entry][paragraph break]";

blank out the whole row;

else if the portal is nowhere and nils is false:

if loop > 9 or a random chance of loop in 10 succeeds:

say "Ein Portal erscheint.[paragraph break]Groß wie eine Tür, aber oval und aus flimmerndem blauen Licht steht es plötzlich mitten im Selbstzahlergehege.[paragraph break][The employee] tut so, als würde [er] es nicht zur Kenntnis nehmen. Vermutlich wittert [er] Stress.";

now the portal is in the self-pay area.

Table of Encounters

event

"Eine gefühlte halbe Schulklasse rauscht durch das Selbstzahlergehege; alles Jungs, außer ein Mädchen. Jeder von ihnen hat nur eine Sache zu bezahlen: Ein Päckchen Kaugummi, eine Dose Energydrink, oder etwas ähnlich ungesundes. Seltsamerweise sind sie so schnell draußen, wie sie hineingerauscht sind, und das alles unter den entspannten Blicken [des employee]."

"Ein Mann mit Kleinkind im Einkaufswagen kommt herein und scannt pürierte Glasnahrung und dickte Windelpakete. Trotz quengelndem Kind hat er im Nu bezahlt und ist wieder verschwunden."

"Eine alte Frau kommt im Schneckentempo an eine Selbstzahlerkasse und scannt mit zitternder Hand ihr Graubrot und ihre Pfefferminzteebeutel. 'Das dauert.' denkst du noch, aber da hält sie schon ihre Quittung an die Schranke und geht langsam wie eine Schildkröte hinaus. Und du kommst dir vor wie Achilles, der sie nicht einholen kann."

"Eine Studentin kommt herein und scannt Rotwein und Gemüse. Sie schenkt dir keinen Blick und ist flott wieder verschwunden."

with 5 blank rows